/*--------------------------------------------------------------
  *
  *                  SAS/STAT TEST LIBRARY
  *
  *       NAME: calis51
  *    SUPPORT: saswmh   Wolfgang M. Hartmann
  *     UPDATE:
  *  REFERENCE: Generalized Multimode Latent Variable Models
  *       DATA: BENTLER, POON & LEE (1988)
  * EVALUATION:
  *   FUNCTION: Three Mode Models in Factor Analysis
  *             Compare GLS and ML results with BENTLER et al(1988)
  *             Serious problems in estimating initial values
  *             Singular central model matrices occur
  *       MISC:
  *
  --------------------------------------------------------------*/

* OPTIONS NODATE NOSTIMER LS=120 PS=60;

TITLE 'CALIS51: Generalized Multimode Models, BENTLER, POON & LEE,1988';
TITLE2 'Four Personality Variables';
DATA BEPOLE(TYPE=CORR);
   _TYPE_ = 'CORR'; INPUT _NAME_ $ EP AP IP MP ET AT IT MT ES AS IS MS;
   LABEL EP='Extraversion-Peer'
         AP='Anxiety-Peer'
         IP='Impulsivity-Peer'
         MP='AchievMotiv-Peer'
         ET='Extraversion-Teacher'
         AT='Anxiety-Teacher'
         IT='Impulsivity-Teacher'
         MT='AchievMotiv-Teacher'
         ES='Extraversion-Self'
         AS='Anxiety-Self'
         IS='Impulsivity-Self'
         MS='AchievMotiv-Self';
   CARDS;

EP   1.    .    .    .    .    .    .    .    .    .    .    .
AP   -.38 1.    .    .    .    .    .    .    .    .    .    .
IP    .42 -.21 1.    .    .    .    .    .    .    .    .    .
MP   -.25  .54 -.54 1.    .    .    .    .    .    .    .    .
ET    .64 -.15  .26 -.05 1.    .    .    .    .    .    .    .
AT   -.29  .66 -.19  .44 -.25 1.0   .    .    .    .    .    .
IT    .38 -.09  .56 -.19  .59 -.14 1.    .    .    .    .    .
MT   -.22  .51 -.33  .66  .06  .62 -.05 1.    .    .    .    .
ES    .45 -.05  .12  .10  .50 -.05  .36  .17 1.    .    .    .
AS    .04  .38 -.03  .14  .08  .30  .09  .16  .02 1.    .    .
IS    .33 -.13  .35 -.18  .41 -.14  .45 -.13  .43  .16 1.    .
MS   -.21  .37 -.44  .58 -.01  .41 -.10  .62  .06  .04 -.37 1.
  ;
RUN;

PROC CALIS DATA=BEPOLE METHOD=GLS TECH=LM OUTRAM=RAM EDF=67 PRINT PMAT;
TITLE3 'Specified Initial Values, like BENTLER et al, 1988';
 LINEQS
      EP = F1 + E1,
      AP = F2 + E2,
      IP = F3 + E3,
      MP = F4 + E4,
      ET = F5 + E5,
      AT = F6 + E6,
      IT = F7 + E7,
      MT = F8 + E8,
      ES = L1(.5) F1 + L2(.3) F5 +  E9,
      AS = L1(.5) F2 + L2(.3) F6 + E10,
      IS = L1(.5) F3 + L2(.3) F7 + E11,
      MS = L1(.5) F4 + L2(.3) F8 + E12,
      F1 = F9,
      F2 = F10,
      F3 = F11,
      F4 = M1(.5) F9  + M2(.8) F10 + M3(-.5) F11,
      F5 = F12,
      F6 = F13,
      F7 = F14,
      F8 = M1(.5) F12 + M2(.8) F13 + M3(-.5) F14,
      F9  = P1( .8)  F15,
      F10 = P2(-.5)  F15 + P3( .6)  F16,
      F11 = P4( .3)  F15 + P5(-.1)  F16 + P6( .7)  F17,
      F12 = P7( .5)  F15 + P8( .1)  F16 + P9( .1)  F17 + P10( .7) F18,
      F13 = P11(-.3) F15 + P12( .5) F16 + P13( .1) F17 + P14(-.2) F18
                         + P15( .5) F19,
      F14 = P16( .3) F15 + P17( .1) F16 + P18( .5) F17 + P19( .3) F18
                         + P20(-.1) F19;
 STD
      E2-E4   = EPS2-EPS4 (3 * .5),
      E6-E12  = EPS6-EPS12(7 * .5),
      F15-F19 = 5 * 1. ;
 BOUNDS
      EPS2-EPS4 >= 0. ,
      EPS6-EPS12 >= 0.;
 RUN;


PROC CALIS DATA=BEPOLE METHOD=MAX TECH=LM INRAM=RAM EDF=67 PRINT PMAT;
 BOUNDS
      EPS2-EPS4 >= 0. ,
      EPS6-EPS12 >= 0.;
 RUN;


PROC CALIS DATA=BEPOLE METHOD=GLS TECH=LM EDF=67 PRINT;
TITLE3 'Automatically Estimated Initial Values';
 LINEQS
      EP = F1 + E1,
      AP = F2 + E2,
      IP = F3 + E3,
      MP = F4 + E4,
      ET = F5 + E5,
      AT = F6 + E6,
      IT = F7 + E7,
      MT = F8 + E8,
      ES = L1 F1 + L2 F5 +  E9,
      AS = L1 F2 + L2 F6 + E10,
      IS = L1 F3 + L2 F7 + E11,
      MS = L1 F4 + L2 F8 + E12,
      F1 = F9,
      F2 = F10,
      F3 = F11,
      F4 = M1 F9  + M2 F10 + M3 F11,
      F5 = F12,
      F6 = F13,
      F7 = F14,
      F8 = M1 F12 + M2 F13 + M3 F14,
      F9  = P1  F15,
      F10 = P2  F15 + P3  F16,
      F11 = P4  F15 + P5  F16 + P6  F17,
      F12 = P7  F15 + P8  F16 + P9  F17 + P10 F18,
      F13 = P11 F15 + P12 F16 + P13 F17 + P14 F18 + P15 F19,
      F14 = P16 F15 + P17 F16 + P18 F17 + P19 F18 + P20 F19;
 STD
      E2-E4   = EPS2-EPS4 (3 * 5.),
      E6-E12  = EPS6-EPS12(7 * 5.),
      F15-F19 = 5 * 1. ;
 BOUNDS
      EPS2-EPS4 >= 0. ,
      EPS6-EPS12 >= 0.;
 RUN;


PROC CALIS DATA=BEPOLE METHOD=GLS TECH=LM EDF=67 PRINT;
TITLE3 'Very Rough Specified Initial Values';
 LINEQS
      EP = F1 + E1,
      AP = F2 + E2,
      IP = F3 + E3,
      MP = F4 + E4,
      ET = F5 + E5,
      AT = F6 + E6,
      IT = F7 + E7,
      MT = F8 + E8,
      ES = L1(.5) F1 + L2(.5) F5 +  E9,
      AS = L1(.5) F2 + L2(.5) F6 + E10,
      IS = L1(.5) F3 + L2(.5) F7 + E11,
      MS = L1(.5) F4 + L2(.5) F8 + E12,
      F1 = F9,
      F2 = F10,
      F3 = F11,
      F4 = M1(.5) F9  + M2(.5) F10 + M3(.5) F11,
      F5 = F12,
      F6 = F13,
      F7 = F14,
      F8 = M1(.5) F12 + M2(.5) F13 + M3(.5) F14,
      F9  = P1(.5)  F15,
      F10 = P2(.5)  F15 + P3(.5)  F16,
      F11 = P4(.5)  F15 + P5(.5)  F16 + P6(.5)  F17,
      F12 = P7(.5)  F15 + P8(.5)  F16 + P9(.5)  F17 + P10(.5) F18,
      F13 = P11(.5) F15 + P12(.5) F16 + P13(.5) F17 + P14(.5) F18 + P15(.5) F19,
      F14 = P16(.5) F15 + P17(.5) F16 + P18(.5) F17 + P19(.5) F18 + P20(.5) F19;
 STD
      E2-E4   = EPS2-EPS4 (3 * 1.),
      E6-E12  = EPS6-EPS12(7 * 1.),
      F15-F19 = 5 * 1. ;
 BOUNDS
      EPS2-EPS4 >= 0. ,
      EPS6-EPS12 >= 0.;
 RUN;